MODULE.bazel

# Copyright 2025 Google LLC
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#      https:#www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

module(
    name = "cel_java",
)

bazel_dep(name = "bazel_skylib", version = "1.9.2")
bazel_dep(name = "rules_jvm_external", version = "7.2")
bazel_dep(name = "protobuf", version = "36.2", repo_name = "com_google_protobuf")
bazel_dep(name = "googleapis", version = "0.0.0-20261020-14a161a9", repo_name = "com_google_googleapis")
bazel_dep(name = "rules_pkg", version = "1.3.0")
bazel_dep(name = "rules_license", version = "1.0.0")
bazel_dep(name = "rules_proto", version = "7.1.0")
bazel_dep(name = "rules_java", version = "9.9.0")
bazel_dep(name = "rules_android", version = "0.7.3")
bazel_dep(name = "rules_shell", version = "0.8.0")
bazel_dep(name = "googleapis-java", version = "1.1.5")
bazel_dep(name = "cel-spec", version = "0.25.3", repo_name = "cel_spec")
bazel_dep(name = "cel-conformance", version = "0.1.0", repo_name = "cel_conformance")

# TODO: Remove git_override and bump cel-spec once a new release is cut on BCR.
git_override(
    module_name = "cel-spec",
    commit = "21ec6f4e52e8d694687ff9ed7408d3eccbb955d7",
    remote = "https://github.com/cel-expr/cel-spec",
)

# TODO: Remove git_override once cel-conformance is published on BCR.
git_override(
    module_name = "cel-conformance",
    commit = "8d64ec2a2938204e388fc02e8e5102dc8ca16e83",
    remote = "https://github.com/cel-expr/cel-conformance",
)

bazel_dep(name = "rules_go", version = "0.65.0")

# Required by cel-spec to satisfy gazelle transitive dependency
go_sdk = use_extension("@rules_go//go:extensions.bzl", "go_sdk")
go_sdk.download(version = "1.27.3")

switched_rules = use_extension("@com_google_googleapis//:extensions.bzl", "switched_rules")
switched_rules.use_languages(java = True)
use_repo(switched_rules, "com_google_googleapis_imports")

maven = use_extension("@rules_jvm_external//:extensions.bzl", "maven")

AUTO_VALUE_VERSION = "1.11.1"

GUAVA_VERSION = "33.7.2"

JLINE_VERSION = "3.30.17"

TRUTH_VERSION = "1.4.5"

PROTOBUF_JAVA_VERSION = "4.36.2"

CEL_VERSION = "0.15.0"

# Compile only artifacts
[
    maven.artifact(
        artifact = artifact,
        group = group,
        neverlink = True,
        version = version,
    )
    for group, artifact, version in [coord.split(":") for coord in [
        "com.google.code.findbugs:annotations:3.0.1",
        "com.google.errorprone:error_prone_annotations:2.51.0",
    ]]
]

# Test only artifacts
[
    maven.artifact(
        testonly = True,
        artifact = artifact,
        group = group,
        version = version,
    )
    for group, artifact, version in [coord.split(":") for coord in [
        "org.mockito:mockito-core:4.11.0",
        "io.github.classgraph:classgraph:4.8.199",
        "com.google.testparameterinjector:test-parameter-injector:1.25",
        "com.google.guava:guava-testlib:" + GUAVA_VERSION + "-jre",
        "com.google.truth.extensions:truth-java8-extension:" + TRUTH_VERSION,
        "com.google.truth.extensions:truth-proto-extension:" + TRUTH_VERSION,
        "com.google.truth.extensions:truth-liteproto-extension:" + TRUTH_VERSION,
        "com.google.truth:truth:" + TRUTH_VERSION,
    ]]
]

maven.install(
    name = "maven",
    # keep sorted
    artifacts = [
        "com.google.auto.value:auto-value:" + AUTO_VALUE_VERSION,
        "com.google.auto.value:auto-value-annotations:" + AUTO_VALUE_VERSION,
        "com.google.guava:guava:" + GUAVA_VERSION + "-jre",
        "com.google.protobuf:protobuf-java:" + PROTOBUF_JAVA_VERSION,
        "com.google.protobuf:protobuf-java-util:" + PROTOBUF_JAVA_VERSION,
        "com.google.re2j:re2j:1.8",
        "info.picocli:picocli:4.7.7",
        "org.antlr:antlr4-runtime:4.13.2",
        "org.freemarker:freemarker:2.3.35",
        "org.jline:jline-reader:" + JLINE_VERSION,
        "org.jline:jline-terminal:" + JLINE_VERSION,
        "org.jspecify:jspecify:1.0.1",
        "org.yaml:snakeyaml:2.7",
        "tools.aqua:z3-turnkey:4.14.1",
    ],
    known_contributing_modules = ["protobuf"],
    repositories = [
        "https://maven.google.com",
        "https://repo1.maven.org/maven2",
    ],
)
maven.install(
    name = "maven_android",
    # keep sorted
    artifacts = [
        "com.google.guava:guava:" + GUAVA_VERSION + "-android",
        "com.google.protobuf:protobuf-javalite:" + PROTOBUF_JAVA_VERSION,
    ],
    repositories = [
        "https://maven.google.com",
        "https://repo1.maven.org/maven2",
    ],
)

# Conformance test only

maven.install(
    name = "maven_conformance",
    artifacts = [
        "dev.cel:cel:" + CEL_VERSION,
        "dev.cel:compiler:" + CEL_VERSION,
        "dev.cel:runtime:" + CEL_VERSION,
    ],
    fail_on_missing_checksum = not CEL_VERSION.endswith("-SNAPSHOT"),
    repositories = [
        "https://maven.google.com",
        "https://repo1.maven.org/maven2",
        "https://central.sonatype.com/repository/maven-snapshots/",
        "m2local",
    ],
)
use_repo(maven, "maven", "maven_android", "maven_conformance")

non_module_dependencies = use_extension("//:repositories.bzl", "non_module_dependencies")
use_repo(non_module_dependencies, "antlr4_jar")
use_repo(non_module_dependencies, "bazel_common")
use_repo(non_module_dependencies, "cel_policy")